Move project to CMake (#781)

* Move to cmake

* Move sources to source_groups and ditch more old VS files

* Add BuildVer.h generation

* Break out cmake source lists to platforms

* Don't copy swf files

* Revert audio changes from merge

* Add platform defines

* Match MSBuild flags

* Move BuildVer.h to common include and fix rebuild issue

* Seperate projects properly

* Exclude more files and make sure GameHDD exists

* Missing line

* Remove remaining VS project files

* Update readme and actions

* Use incremental LTCG

* Update workflows

* Update build workflows and output folder

* Disable vcpkg checks

* Force MSVC

* Use precompiled headers

* Only use PCH for cpp

* Exclude compat_shims from PCH

* Handle per-platform source includes

* Copy only current platform media

* Define Iggy libs per platform

* Fix EnsureGameHDD check

* Only set WIN32_EXECUTABLE on Windows

* Correct Iggy libs path

* Remove include of terrain_MipmapLevel

* Correct path to xsb/xwb

* Implement copilot suggestions

* Add clang flags (untested)

* Fix robocopy error checking

* Update documentation

* Drop CMakePresets.json version as we dont use v6 features

* Always cleanup artifacts in nightly even if some builds fail

* Re-work compiler target options

* Move newer iggy dll into redist and cleanup

* Fix typos

* Remove 'Source Files' from all source groups

* Remove old ps1 build scripts

1 files changed, 85 insertions, 0 deletions

diff --git a/Minecraft.Server/CMakeLists.txt b/Minecraft.Server/CMakeLists.txt
new file mode 100644
index 00000000..52e5826e
--- /dev/null
+++ b/Minecraft.Server/CMakeLists.txt
@@ -0,0 +1,85 @@
+# Note: A lot of this file is the same as the client due to the shared code
+
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/Common.cmake")
+
+include("${CMAKE_SOURCE_DIR}/cmake/CommonSources.cmake")
+
+# Combine all source files into a single variable for the target
+# We cant use CMAKE_CONFIGURE_PRESET here as VS doesn't set it, so just rely on the folder
+set(MINECRAFT_SERVER_SOURCES
+  ${MINECRAFT_SERVER_COMMON}
+  ${SOURCES_COMMON}
+)
+
+add_executable(Minecraft.Server ${MINECRAFT_SERVER_SOURCES})
+
+target_include_directories(Minecraft.Server PRIVATE
+  "${CMAKE_BINARY_DIR}/generated/" # This is for the generated BuildVer.h
+  "${CMAKE_SOURCE_DIR}/Minecraft.Client/"
+  "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/Iggy/include"
+  "${CMAKE_CURRENT_SOURCE_DIR}"
+  "${CMAKE_SOURCE_DIR}/include/"
+)
+target_compile_definitions(Minecraft.Server PRIVATE
+  ${MINECRAFT_SHARED_DEFINES}
+  MINECRAFT_SERVER_BUILD
+)
+target_precompile_headers(Minecraft.Server PRIVATE "$<$<COMPILE_LANGUAGE:CXX>:stdafx.h>")
+set_source_files_properties("${CMAKE_SOURCE_DIR}/Minecraft.Client/compat_shims.cpp" PROPERTIES SKIP_PRECOMPILE_HEADERS ON) # This redefines internal MSVC CRT symbols which will cause an issue with PCH
+
+configure_compiler_target(Minecraft.Server)
+
+set_target_properties(Minecraft.Server PROPERTIES
+  OUTPUT_NAME "Minecraft.Server"
+  VS_DEBUGGER_WORKING_DIRECTORY "$<TARGET_FILE_DIR:Minecraft.Server>"
+  VS_DEBUGGER_COMMAND_ARGUMENTS "-port 25565 -bind 0.0.0.0 -name DedicatedServer"
+)
+
+target_link_libraries(Minecraft.Server PRIVATE
+  Minecraft.World
+  d3d11
+  d3dcompiler
+  XInput9_1_0
+  wsock32
+  legacy_stdio_definitions
+  $<$<CONFIG:Debug>: # Debug 4J libraries
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Input_d.lib"
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Storage_d.lib"
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Render_PC_d.lib"
+  >
+  $<$<NOT:$<CONFIG:Debug>>: # Release 4J libraries
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Input.lib"
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Storage.lib"
+    "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/4JLibs/libs/4J_Render_PC.lib"
+  >
+)
+
+# Iggy libs
+foreach(lib IN LISTS IGGY_LIBS)
+  target_link_libraries(Minecraft.Server PRIVATE "${CMAKE_SOURCE_DIR}/Minecraft.Client/${PLATFORM_NAME}/Iggy/lib/${lib}")
+endforeach()
+
+# ---
+# Asset / redist copy
+# ---
+include("${CMAKE_SOURCE_DIR}/cmake/CopyAssets.cmake")
+
+# Copy res
+set(ASSET_FOLDER_PAIRS
+  "${CMAKE_SOURCE_DIR}/Minecraft.Client/Common/res"         "Common/res"
+)
+setup_asset_folder_copy(Minecraft.Server "${ASSET_FOLDER_PAIRS}")
+
+# Copy arc media
+set(ASSET_FILES_PAIRS
+  "${CMAKE_SOURCE_DIR}/Minecraft.Client/Common/Media/MediaWindows64.arc" "Common/Media/"
+)
+setup_asset_file_copy(Minecraft.Server "${ASSET_FILES_PAIRS}")
+
+# Copy redist files
+add_copyredist_target(Minecraft.Server)
+
+# Make sure GameHDD exists on Windows
+if(PLATFORM_NAME STREQUAL "Windows64")
+  add_gamehdd_target(Minecraft.Server)
+endif()