Move project to CMake (#781)

* Move to cmake

* Move sources to source_groups and ditch more old VS files

* Add BuildVer.h generation

* Break out cmake source lists to platforms

* Don't copy swf files

* Revert audio changes from merge

* Add platform defines

* Match MSBuild flags

* Move BuildVer.h to common include and fix rebuild issue

* Seperate projects properly

* Exclude more files and make sure GameHDD exists

* Missing line

* Remove remaining VS project files

* Update readme and actions

* Use incremental LTCG

* Update workflows

* Update build workflows and output folder

* Disable vcpkg checks

* Force MSVC

* Use precompiled headers

* Only use PCH for cpp

* Exclude compat_shims from PCH

* Handle per-platform source includes

* Copy only current platform media

* Define Iggy libs per platform

* Fix EnsureGameHDD check

* Only set WIN32_EXECUTABLE on Windows

* Correct Iggy libs path

* Remove include of terrain_MipmapLevel

* Correct path to xsb/xwb

* Implement copilot suggestions

* Add clang flags (untested)

* Fix robocopy error checking

* Update documentation

* Drop CMakePresets.json version as we dont use v6 features

* Always cleanup artifacts in nightly even if some builds fail

* Re-work compiler target options

* Move newer iggy dll into redist and cleanup

* Fix typos

* Remove 'Source Files' from all source groups

* Remove old ps1 build scripts

1 files changed, 96 insertions, 0 deletions

diff --git a/Minecraft.Client/CMakeLists.txt b/Minecraft.Client/CMakeLists.txt
new file mode 100644
index 00000000..9f75efd2
--- /dev/null
+++ b/Minecraft.Client/CMakeLists.txt
@@ -0,0 +1,96 @@
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/Common.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/Durango.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/ORBIS.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/PS3.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/PSVita.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/Windows.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cmake/sources/Xbox360.cmake")
+
+include("${CMAKE_SOURCE_DIR}/cmake/CommonSources.cmake")
+
+include("${CMAKE_SOURCE_DIR}/cmake/Utils.cmake")
+
+# Combine all source files into a single variable for the target
+# We cant use CMAKE_CONFIGURE_PRESET here as VS doesn't set it, so just rely on the folder
+set(MINECRAFT_CLIENT_SOURCES
+  ${MINECRAFT_CLIENT_COMMON}
+  $<$<STREQUAL:${PLATFORM_NAME},Durango>:${MINECRAFT_CLIENT_DURANGO}>
+  $<$<STREQUAL:${PLATFORM_NAME},Orbis>:${MINECRAFT_CLIENT_ORBIS}>
+  $<$<STREQUAL:${PLATFORM_NAME},PS3>:${MINECRAFT_CLIENT_PS3}>
+  $<$<STREQUAL:${PLATFORM_NAME},PSVita>:${MINECRAFT_CLIENT_PSVITA}>
+  $<$<STREQUAL:${PLATFORM_NAME},Windows64>:${MINECRAFT_CLIENT_WINDOWS}>
+  $<$<STREQUAL:${PLATFORM_NAME},Xbox>:${MINECRAFT_CLIENT_XBOX360}>
+  ${SOURCES_COMMON}
+)
+
+add_executable(Minecraft.Client ${MINECRAFT_CLIENT_SOURCES})
+
+# Only define executable on windows
+if(PLATFORM_NAME STREQUAL "Windows64")
+  set_target_properties(Minecraft.Client PROPERTIES WIN32_EXECUTABLE TRUE)
+endif()
+
+target_include_directories(Minecraft.Client PRIVATE
+  "${CMAKE_BINARY_DIR}/generated/" # This is for the generated BuildVer.h
+  "${CMAKE_CURRENT_SOURCE_DIR}"
+  "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/Iggy/include"
+  "${CMAKE_SOURCE_DIR}/include/"
+)
+target_compile_definitions(Minecraft.Client PRIVATE
+  ${MINECRAFT_SHARED_DEFINES}
+)
+target_precompile_headers(Minecraft.Client PRIVATE "$<$<COMPILE_LANGUAGE:CXX>:stdafx.h>")
+set_source_files_properties(compat_shims.cpp PROPERTIES SKIP_PRECOMPILE_HEADERS ON) # This redefines internal MSVC CRT symbols which will cause an issue with PCH
+
+configure_compiler_target(Minecraft.Client)
+
+set_target_properties(Minecraft.Client PROPERTIES
+  OUTPUT_NAME "Minecraft.Client"
+  VS_DEBUGGER_WORKING_DIRECTORY "$<TARGET_FILE_DIR:Minecraft.Client>"
+)
+
+target_link_libraries(Minecraft.Client PRIVATE
+  Minecraft.World
+  d3d11
+  d3dcompiler
+  XInput9_1_0
+  wsock32
+  legacy_stdio_definitions
+  $<$<CONFIG:Debug>: # Debug 4J libraries
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Input_d.lib"
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Storage_d.lib"
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Render_PC_d.lib"
+  >
+  $<$<NOT:$<CONFIG:Debug>>: # Release 4J libraries
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Input.lib"
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Storage.lib"
+    "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/4JLibs/libs/4J_Render_PC.lib"
+  >
+)
+
+# Iggy libs
+foreach(lib IN LISTS IGGY_LIBS)
+  target_link_libraries(Minecraft.Client PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}/Iggy/lib/${lib}")
+endforeach()
+
+# ---
+# Asset / redist copy
+# ---
+include("${CMAKE_SOURCE_DIR}/cmake/CopyAssets.cmake")
+set(ASSET_FOLDER_PAIRS
+  "${CMAKE_CURRENT_SOURCE_DIR}/music"                  "music"
+  "${CMAKE_CURRENT_SOURCE_DIR}/Common/Media"           "Common/Media"
+  "${CMAKE_CURRENT_SOURCE_DIR}/Common/res"             "Common/res"
+  "${CMAKE_CURRENT_SOURCE_DIR}/Common/Trial"           "Common/Trial"
+  "${CMAKE_CURRENT_SOURCE_DIR}/Common/Tutorial"        "Common/Tutorial"
+  "${CMAKE_CURRENT_SOURCE_DIR}/${PLATFORM_NAME}Media"  "${PLATFORM_NAME}Media"
+)
+setup_asset_folder_copy(Minecraft.Client "${ASSET_FOLDER_PAIRS}")
+
+# Copy redist files
+add_copyredist_target(Minecraft.Client)
+
+# Make sure GameHDD exists on Windows
+if(PLATFORM_NAME STREQUAL "Windows64")
+  add_gamehdd_target(Minecraft.Client)
+endif()